From ccd380db3639ba349ee3407c995ecb8320906abc Mon Sep 17 00:00:00 2001
From: pika <alex@team-pieck.de>
Date: Mon, 28 Oct 2024 11:14:33 +0100
Subject: [PATCH] addet command not found plugin

---
 .zsh/custom/command-not-found.plugin.zsh | 70 ++++++++++++++++++++++++
 .zshrc                                   |  2 +
 2 files changed, 72 insertions(+)
 create mode 100644 .zsh/custom/command-not-found.plugin.zsh

diff --git a/.zsh/custom/command-not-found.plugin.zsh b/.zsh/custom/command-not-found.plugin.zsh
new file mode 100644
index 0000000..c741e18
--- /dev/null
+++ b/.zsh/custom/command-not-found.plugin.zsh
@@ -0,0 +1,70 @@
+## Platforms with a built-in command-not-found handler init file
+
+for file (
+  # Arch Linux. Must have pkgfile installed: https://wiki.archlinux.org/index.php/Pkgfile#Command_not_found
+  /usr/share/doc/pkgfile/command-not-found.zsh
+  # Homebrew: https://github.com/Homebrew/homebrew-command-not-found
+  /opt/homebrew/Library/Taps/homebrew/homebrew-command-not-found/handler.sh
+  /usr/local/Homebrew/Library/Taps/homebrew/homebrew-command-not-found/handler.sh
+  /home/linuxbrew/.linuxbrew/Homebrew/Library/Taps/homebrew/homebrew-command-not-found/handler.sh
+); do
+  if [[ -r "$file" ]]; then
+    source "$file"
+    unset file
+    return 0
+  fi
+done
+unset file
+
+
+## Platforms with manual command_not_found_handler() setup
+
+# Debian and derivatives: https://launchpad.net/ubuntu/+source/command-not-found
+if [[ -x /usr/lib/command-not-found || -x /usr/share/command-not-found/command-not-found ]]; then
+  command_not_found_handler() {
+    if [[ -x /usr/lib/command-not-found ]]; then
+      /usr/lib/command-not-found -- "$1"
+      return $?
+    elif [[ -x /usr/share/command-not-found/command-not-found ]]; then
+      /usr/share/command-not-found/command-not-found -- "$1"
+      return $?
+    else
+      printf "zsh: command not found: %s\n" "$1" >&2
+      return 127
+    fi
+  }
+fi
+
+# Fedora: https://fedoraproject.org/wiki/Features/PackageKitCommandNotFound
+if [[ -x /usr/libexec/pk-command-not-found ]]; then
+  command_not_found_handler() {
+    if [[ -S /var/run/dbus/system_bus_socket && -x /usr/libexec/packagekitd ]]; then
+      /usr/libexec/pk-command-not-found "$@"
+      return $?
+    fi
+
+    printf "zsh: command not found: %s\n" "$1" >&2
+    return 127
+  }
+fi
+
+# NixOS: https://github.com/NixOS/nixpkgs/tree/master/nixos/modules/programs/command-not-found
+if [[ -x /run/current-system/sw/bin/command-not-found ]]; then
+  command_not_found_handler() {
+    /run/current-system/sw/bin/command-not-found "$@"
+  }
+fi
+
+# Termux: https://github.com/termux/command-not-found
+if [[ -x /data/data/com.termux/files/usr/libexec/termux/command-not-found ]]; then
+  command_not_found_handler() {
+    /data/data/com.termux/files/usr/libexec/termux/command-not-found "$1"
+  }
+fi
+
+# SUSE and derivates: https://www.unix.com/man-page/suse/1/command-not-found/
+if [[ -x /usr/bin/command-not-found ]]; then
+  command_not_found_handler() {
+    /usr/bin/command-not-found "$1"
+  }
+fi
diff --git a/.zshrc b/.zshrc
index 3c3e2e5..fa31720 100644
--- a/.zshrc
+++ b/.zshrc
@@ -154,6 +154,7 @@ _init (){
   local zAutopairs="$zconf/autopairs/autopair.zsh"
   local zFzfCd="$zconf/custom/zsh-interactive-cd.plugin.zsh"
   local zAgentManagement="$zconf/custom/agent.zsh"
+  local zCommandNotFound="$zconf/custom/command-not-found.plugin.zsh"
 
   local _pluginlist=(
   "$zAutosg"
@@ -162,6 +163,7 @@ _init (){
   "$zAutopairs"
   "$zFzfCd"
   "$zAgentManagement"
+  "$zCommandNotFound"
 )
 
 DEBUG_PLUG=""